Создать облачный сервер произвольной конфигурации с загрузочным сетевым диском и дополнительным сетевым диском

Создать облачный сервер произвольной конфигурации с загрузочным сетевым диском и дополнительным сетевым диском

Мы рекомендуем создавать ресурсы по порядку. Если вы единовременно создаете все ресурсы, которые описаны в конфигурационном файле, может возникнуть ошибка — Terraform создает ресурсы независимо от порядка, в котором они перечислены в файле.

Опционально: настройте провайдеры.
Создайте пару SSH-ключей.
Создайте флейвор с сетевым диском.
Создайте приватную сеть и подсеть.
Создайте облачный роутер, подключенный к внешней сети.
Создайте порт для облачного сервера.
Получите образ.
Создайте загрузочный сетевой диск.
Создайте дополнительный сетевой диск.
Создайте облачный сервер.
Создайте публичный IP-адрес.
Назначьте ассоциацию публичного и приватного IP-адреса облачного сервера.
Получите IP-адрес облачного сервера.

Конфигурационные файлы⁠

Пример файла для настройки провайдеров

terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "5.0.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "1.54.1"
    }
  }
}

provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
}

resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}

resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Пример файла для создания сервера

resource "selectel_vpc_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
}

resource "openstack_compute_flavor_v2" "flavor_1" {
  name      = "custom-flavor-with-network-volume"
  vcpus     = 2
  ram       = 2048
  disk      = 0
  is_public = false

  lifecycle {
    create_before_destroy = true
  }

}

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

resource "openstack_networking_port_v2" "port_1" {
  name       = "port"
  network_id = openstack_networking_network_v2.network_1.id

  fixed_ip {
    subnet_id = openstack_networking_subnet_v2.subnet_1.id
  }
}

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

resource "openstack_blockstorage_volume_v3" "volume_1" {
  name        = "boot-volume-for-server"
  size        = "5"
  image_id    = data.openstack_images_image_v2.image_1.id
  volume_type = "fast.ru-9a"

  lifecycle {
    ignore_changes = [image_id]
  }
}

resource "openstack_blockstorage_volume_v3" "volume_2" {
  name              = "additional-volume-for-server"
  size              = "7"
  volume_type       = "universal.ru-9a"
}

resource "openstack_compute_instance_v2" "server_1" {
  name              = "server"
  flavor_id         = openstack_compute_flavor_v2.flavor_1.id
  key_pair          = selectel_vpc_keypair_v2.keypair_1.name
  availability_zone = "ru-9a"

  network {
    port = openstack_networking_port_v2.port_1.id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_1.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_2.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = -1
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

resource "openstack_networking_floatingip_v2" "floatingip_1" {
  pool = "external-network"
}

resource "openstack_networking_floatingip_associate_v2" "association_1" {
  port_id     = openstack_networking_port_v2.port_1.id
  floating_ip = openstack_networking_floatingip_v2.floatingip_1.address
}

output "public_ip_address" {
  value = openstack_networking_floatingip_v2.floatingip_1.fixed_ip
}

1. Опционально: настроить провайдеры⁠

Если вы настроили провайдеры Selectel и OpenStack, пропустите этот шаг.

Создайте директорию для хранения конфигурационных файлов и файл с расширением .tf.
Добавьте провайдеры Selectel и OpenStack:
```
terraform {
  required_providers {
    selectel  = {
      source  = "selectel/selectel"
      version = "5.0.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "1.54.1"
    }
  }
}
```
Здесь version — версии провайдеров. Актуальную версию можно посмотреть в документации Selectel (в Terraform Registry и GitHub) и OpenStack (в Terraform Registry и GitHub).

Подробнее о продуктах, услугах и сервисах, которыми можно управлять с помощью провайдеров, в инструкции Провайдеры Selectel и OpenStack.
Инициализируйте провайдер Selectel:
```
provider "selectel" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
}
```
Здесь:
- domain_name — номер аккаунта Selectel. Можно посмотреть в панели управления в правом верхнем углу;
- username — имя сервисного пользователя с ролями Администратор аккаунта и Администратор пользователей. Можно посмотреть в панели управления: откройте меню (номер аккаунта) в правом верхнем углу → выберите пункт Профиль и настройки → раздел Управление пользователями → вкладка Сервисные пользователи (раздел доступен только Владельцу аккаунта и Администратору пользователей);
- password — пароль сервисного пользователя. Можно посмотреть при создании пользователя или изменить на новый.
Создайте проект облачной платформы:
```
resource "selectel_vpc_project_v2" "project_1" {
  name = "project"
}
```
Посмотрите подробное описание ресурса selectel_vpc_project_v2.
Создайте сервисного пользователя для доступа к проекту и назначьте ему роль Администратор проекта:
```
resource "selectel_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = selectel_vpc_project_v2.project_1.id 
  }
}
```
Здесь:
- username — имя пользователя;
- password — пароль пользователя. Пароль должен быть не короче восьми символов и содержать латинские буквы разных регистров и цифры;
- project_id — ID проекта облачной платформы. В панели управления перейдите в раздел Облачная платформа → откройте меню проектов (название текущего проекта) → в строке нужного проекта нажмите .
Посмотрите подробное описание ресурса selectel_iam_serviceuser_v1.
Инициализируйте провайдер OpenStack:
```
provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = selectel_vpc_project_v2.project_1.id
  user_name   = selectel_iam_serviceuser_v1.serviceuser_1.name
  password    = selectel_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}
```
Здесь:
- domain_name — номер аккаунта Selectel. Можно посмотреть в панели управления в правом верхнем углу;
- region — пул, например ru-9. Все ресурсы будут создаваться в этом пуле. Список доступных пулов можно посмотреть в инструкции Матрицы доступности.
Опционально: если вы хотите использовать зеркало, создайте отдельный конфигурационный файл Terraform CLI и добавьте в него блок:
```
provider_installation {
  network_mirror {
    url = "https://mirror.selectel.ru/3rd-party/terraform-registry/"
    include = ["registry.terraform.io/*/*"]
  }
  direct {
    exclude = ["registry.terraform.io/*/*"]
  }
}
```
Подробнее о настройках зеркал в инструкции CLI Configuration File документации HashiCorp.
Инициализируйте конфигурацию Terraform в директории:
```
terraform init
```
Проверьте, что конфигурационный файл составлен без ошибок:
```
terraform validate
```
Отформатируйте конфигурационный файл:
```
terraform fmt
```
Проверьте, какие ресурсы будут созданы:
```
terraform plan
```
Примените изменения и создайте ресурсы:
```
terraform apply
```
Подтвердите создание — введите yes и нажмите Enter. Созданные ресурсы отобразятся в панели управления.
Если для создания ресурсов оказалось недостаточно квот, увеличьте квоты.

2. Создать пару SSH-ключей⁠

resource "selectel_vpc_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = selectel_iam_serviceuser_v1.serviceuser_1.id
}

Здесь public_key — путь до публичного SSH-ключа. Если SSH-ключи не созданы, сгенерируйте их.

Посмотрите подробное описание ресурса selectel_vpc_keypair_v2.

3. Создать флейвор с сетевым диском⁠

resource "openstack_compute_flavor_v2" "flavor_1" {
  name      = "custom-flavor-with-network-volume"
  vcpus     = 2
  ram       = 2048
  disk      = 0
  is_public = false

  lifecycle {
    create_before_destroy = true
  }

}

Здесь:

vcpus — количество vCPU;
ram — размер оперативной памяти в МБ;
disk — размер локального диска в ГБ. Для создания флейвора с сетевым диском значение должно быть равно нулю.

Учитывайте ограничения произвольных конфигураций.

Посмотрите подробное описание ресурса openstack_compute_flavor_v2.

4. Создать приватную сеть и подсеть⁠

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Здесь cidr — CIDR приватной подсети, например 192.168.199.0/24.

Посмотрите подробное описание ресурсов:

5. Создать облачный роутер, подключенный к внешней сети⁠

Облачный роутер, подключенный к внешней сети, выполняет функцию 1:1 NAT для доступа из приватной сети в интернет через публичный IP-адрес роутера.

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

Посмотрите подробное описание ресурсов:

6. Создать порт для облачного сервера⁠

resource "openstack_networking_port_v2" "port_1" {
  name       = "port"
  network_id = openstack_networking_network_v2.network_1.id

  fixed_ip {
    subnet_id = openstack_networking_subnet_v2.subnet_1.id
  }
}

Посмотрите подробное описание ресурса openstack_networking_port_v2.

7. Получить образ⁠

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

Посмотрите подробное описание источника данных openstack_images_image_v2.

8. Создать загрузочный сетевой диск⁠

resource "openstack_blockstorage_volume_v3" "volume_1" {
  name        = "boot-volume-for-server"
  size        = "5"
  image_id    = data.openstack_images_image_v2.image_1.id
  volume_type = "fast.ru-9a"

  lifecycle {
    ignore_changes = [image_id]
  }
}

Здесь:

size — размер сетевого диска в ГБ. Посмотрите ограничения размера дисков;
volume_type — тип сетевого диска в формате <type>.<pool_segment>, например basic.ru-9a:
- <type> — basic, universal или fast;
- <pool_segment> — сегмент пула, в котором будет создан сетевой диск, например ru-9a.

Посмотрите подробное описание ресурса openstack_blockstorage_volume_v3.

9. Создать дополнительный сетевой диск⁠

resource "openstack_blockstorage_volume_v3" "volume_2" {
  name              = "additional-volume-for-server"
  size              = "7"
  volume_type       = "universal.ru-9a"
}

Здесь:

size — размер сетевого диска в ГБ. Посмотрите ограничения размера дисков;
volume_type — тип сетевого диска в формате <type>.<pool_segment>, например basic.ru-9a:
- <type> — basic, universal или fast;
- <pool_segment> — сегмент пула, в котором будет создан сетевой диск, например ru-9a.

Посмотрите подробное описание ресурса openstack_blockstorage_volume_v3.

10. Создать облачный сервер⁠

resource "openstack_compute_instance_v2" "server_1" {
  name              = "server"
  flavor_id         = openstack_compute_flavor_v2.flavor_1.id
  key_pair          = selectel_vpc_keypair_v2.keypair_1.name
  availability_zone = "ru-9a"

  network {
    port = openstack_networking_port_v2.port_1.id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_1.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_2.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = -1
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

Здесь <availability_zone> — сегмент пула, в котором будет создан сетевой диск, например ru-9a.

Посмотрите подробное описание ресурса openstack_compute_instance_v2.

11. Создать публичный IP-адрес⁠

resource "openstack_networking_floatingip_v2" "floatingip_1" {
  pool = "external-network"
}

Посмотрите подробное описание ресурса openstack_networking_floatingip_v2.

12. Назначить ассоциацию публичного и приватного IP-адреса облачного сервера⁠

Публичный IP-адрес будет подключен к порту облачного сервера и ассоциирован с приватным IP.

resource "openstack_networking_floatingip_associate_v2" "association_1" {
  port_id     = openstack_networking_port_v2.port_1.id
  floating_ip = openstack_networking_floatingip_v2.floatingip_1.address
}

Посмотрите подробное описание ресурса openstack_networking_floatingip_associate_v2.

13. Получить IP-адрес облачного сервера⁠

output "public_ip_address" {
  value = openstack_networking_floatingip_v2.floatingip_1.fixed_ip
}

Создать облачный сервер произвольной конфигурации с загрузочным сетевым диском и дополнительным сетевым диском

Конфигурационные файлы⁠​

1. Опционально: настроить провайдеры⁠​

2. Создать пару SSH-ключей⁠​

3. Создать флейвор с сетевым диском⁠​

4. Создать приватную сеть и подсеть⁠​

5. Создать облачный роутер, подключенный к внешней сети⁠​

6. Создать порт для облачного сервера⁠​

7. Получить образ⁠​

8. Создать загрузочный сетевой диск⁠​

9. Создать дополнительный сетевой диск⁠​

10. Создать облачный сервер⁠​

11. Создать публичный IP-адрес⁠​

12. Назначить ассоциацию публичного и приватного IP-адреса облачного сервера⁠​

13. Получить IP-адрес облачного сервера⁠​

Конфигурационные файлы⁠

1. Опционально: настроить провайдеры⁠

2. Создать пару SSH-ключей⁠

3. Создать флейвор с сетевым диском⁠

4. Создать приватную сеть и подсеть⁠

5. Создать облачный роутер, подключенный к внешней сети⁠

6. Создать порт для облачного сервера⁠

7. Получить образ⁠

8. Создать загрузочный сетевой диск⁠

9. Создать дополнительный сетевой диск⁠

10. Создать облачный сервер⁠

11. Создать публичный IP-адрес⁠

12. Назначить ассоциацию публичного и приватного IP-адреса облачного сервера⁠

13. Получить IP-адрес облачного сервера⁠